mirror of
https://github.com/varun-r-mallya/sysprof.git
synced 2025-12-31 20:36:25 +00:00
29c4ec495f
This is a major redesign a modernization of Sysprof. The core data structures and design are largely the same, but it has been ported to Gtk3 and has lots of additions that should make your profiling experience smoother. Especially for those that are new to profiling. There are some very simple help docs added, but we really need the experts to come in and write some documentation here.
76 lines
2.7 KiB
Plaintext
76 lines
2.7 KiB
Plaintext
# =============================================================================
|
|
# http://www.gnu.org/software/autoconf-archive/ax_compiler_flags_ldflags.html
|
|
# =============================================================================
|
|
#
|
|
# SYNOPSIS
|
|
#
|
|
# AX_COMPILER_FLAGS_LDFLAGS([VARIABLE], [IS-RELEASE], [EXTRA-BASE-FLAGS], [EXTRA-YES-FLAGS])
|
|
#
|
|
# DESCRIPTION
|
|
#
|
|
# Add warning flags for the linker to VARIABLE, which defaults to
|
|
# WARN_LDFLAGS. VARIABLE is AC_SUBST-ed by this macro, but must be
|
|
# manually added to the LDFLAGS variable for each target in the code base.
|
|
#
|
|
# This macro depends on the environment set up by AX_COMPILER_FLAGS.
|
|
# Specifically, it uses the value of $ax_enable_compile_warnings to decide
|
|
# which flags to enable.
|
|
#
|
|
# LICENSE
|
|
#
|
|
# Copyright (c) 2014, 2015 Philip Withnall <philip@tecnocode.co.uk>
|
|
#
|
|
# Copying and distribution of this file, with or without modification, are
|
|
# permitted in any medium without royalty provided the copyright notice
|
|
# and this notice are preserved. This file is offered as-is, without any
|
|
# warranty.
|
|
|
|
#serial 5
|
|
|
|
AC_DEFUN([AX_COMPILER_FLAGS_LDFLAGS],[
|
|
AX_REQUIRE_DEFINED([AX_APPEND_LINK_FLAGS])
|
|
AX_REQUIRE_DEFINED([AX_APPEND_FLAG])
|
|
AX_REQUIRE_DEFINED([AX_CHECK_COMPILE_FLAG])
|
|
|
|
# Variable names
|
|
m4_define(ax_warn_ldflags_variable,
|
|
[m4_normalize(ifelse([$1],,[WARN_LDFLAGS],[$1]))])
|
|
|
|
# Always pass -Werror=unknown-warning-option to get Clang to fail on bad
|
|
# flags, otherwise they are always appended to the warn_ldflags variable,
|
|
# and Clang warns on them for every compilation unit.
|
|
# If this is passed to GCC, it will explode, so the flag must be enabled
|
|
# conditionally.
|
|
AX_CHECK_COMPILE_FLAG([-Werror=unknown-warning-option],[
|
|
ax_compiler_flags_test="-Werror=unknown-warning-option"
|
|
],[
|
|
ax_compiler_flags_test=""
|
|
])
|
|
|
|
# Base flags
|
|
AX_APPEND_LINK_FLAGS([ dnl
|
|
-Wl,--no-as-needed dnl
|
|
$3 dnl
|
|
],ax_warn_ldflags_variable,[$ax_compiler_flags_test])
|
|
|
|
AS_IF([test "$ax_enable_compile_warnings" != "no"],[
|
|
# "yes" flags
|
|
AX_APPEND_LINK_FLAGS([$4 $5 $6 $7],
|
|
ax_warn_ldflags_variable,
|
|
[$ax_compiler_flags_test])
|
|
])
|
|
AS_IF([test "$ax_enable_compile_warnings" = "error"],[
|
|
# "error" flags; -Werror has to be appended unconditionally because
|
|
# it's not possible to test for
|
|
#
|
|
# suggest-attribute=format is disabled because it gives too many false
|
|
# positives
|
|
AX_APPEND_LINK_FLAGS([ dnl
|
|
-Wl,--fatal-warnings dnl
|
|
],ax_warn_ldflags_variable,[$ax_compiler_flags_test])
|
|
])
|
|
|
|
# Substitute the variables
|
|
AC_SUBST(ax_warn_ldflags_variable)
|
|
])dnl AX_COMPILER_FLAGS
|