mirror of
https://github.com/varun-r-mallya/sysprof.git
synced 2025-12-31 20:36:25 +00:00
29c4ec495f
This is a major redesign a modernization of Sysprof. The core data structures and design are largely the same, but it has been ported to Gtk3 and has lots of additions that should make your profiling experience smoother. Especially for those that are new to profiling. There are some very simple help docs added, but we really need the experts to come in and write some documentation here.
49 lines
1.5 KiB
Plaintext
49 lines
1.5 KiB
Plaintext
# printf-posix.m4 serial 6 (gettext-0.18.2)
|
|
dnl Copyright (C) 2003, 2007, 2009-2015 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Bruno Haible.
|
|
dnl Test whether the printf() function supports POSIX/XSI format strings with
|
|
dnl positions.
|
|
|
|
AC_DEFUN([gt_PRINTF_POSIX],
|
|
[
|
|
AC_REQUIRE([AC_PROG_CC])
|
|
AC_CACHE_CHECK([whether printf() supports POSIX/XSI format strings],
|
|
gt_cv_func_printf_posix,
|
|
[
|
|
AC_RUN_IFELSE(
|
|
[AC_LANG_SOURCE([[
|
|
#include <stdio.h>
|
|
#include <string.h>
|
|
/* The string "%2$d %1$d", with dollar characters protected from the shell's
|
|
dollar expansion (possibly an autoconf bug). */
|
|
static char format[] = { '%', '2', '$', 'd', ' ', '%', '1', '$', 'd', '\0' };
|
|
static char buf[100];
|
|
int main ()
|
|
{
|
|
sprintf (buf, format, 33, 55);
|
|
return (strcmp (buf, "55 33") != 0);
|
|
}]])],
|
|
[gt_cv_func_printf_posix=yes],
|
|
[gt_cv_func_printf_posix=no],
|
|
[
|
|
AC_EGREP_CPP([notposix], [
|
|
#if defined __NetBSD__ || defined __BEOS__ || defined _MSC_VER || defined __MINGW32__ || defined __CYGWIN__
|
|
notposix
|
|
#endif
|
|
],
|
|
[gt_cv_func_printf_posix="guessing no"],
|
|
[gt_cv_func_printf_posix="guessing yes"])
|
|
])
|
|
])
|
|
case $gt_cv_func_printf_posix in
|
|
*yes)
|
|
AC_DEFINE([HAVE_POSIX_PRINTF], [1],
|
|
[Define if your printf() function supports format strings with positions.])
|
|
;;
|
|
esac
|
|
])
|